The Glitch Apple Disk Collection/2014.glitch.apple.collection.zip/indexed/33MASTER.DSK/PHONE LIST.bas

BASIC Source File | 2014-09-09 | 18KB | 343 lines

100  REM ***********************
101  REM *                     *
102  REM *    W A R N I N G    *
103  REM *    - - - - - - -    *
104  REM *                     *
105  REM *    DO NOT MODIFY    *
106  REM *  ANY LINE IN THIS   *
107  REM *   PROGRAM WITH A    *
108  REM *  LINE NUMBER LESS   *
109  REM *     THAN 400!!      *
110  REM *                     *
111  REM *    PROGRAM WILL     *
112  REM *   SELF-DESTRUCT!    *
113  REM *                     *
114  REM ***********************
115  REM <CTRL-J><CTRL-J>
200  DATA 1000
201  DATA \.......................................
202  DATA \.......................................
203  DATA \.......................................
204  DATA \.......................................
205  DATA \.......................................
206  DATA \.......................................
207  DATA \.......................................
208  DATA \.......................................
209  DATA \.......................................
210  DATA \.......................................
211  DATA \.......................................
212  DATA \.......................................
213  DATA \.......................................
214  DATA \.......................................
215  DATA \.......................................
216  DATA \.......................................
217  DATA \.......................................
218  DATA \.......................................
219  DATA \.......................................
220  DATA \.......................................
221  DATA \.......................................
222  DATA \.......................................
223  DATA \.......................................
224  DATA \.......................................
225  DATA \.......................................
226  DATA \.......................................
227  DATA \.......................................
228  DATA \.......................................
229  DATA \.......................................
230  DATA \.......................................
231  DATA \.......................................
232  DATA \.......................................
233  DATA \.......................................
234  DATA \.......................................
235  DATA \.......................................
236  DATA \.......................................
237  DATA \.......................................
238  DATA \.......................................
239  DATA \.......................................
240  DATA \.......................................
241  DATA \.......................................
242  DATA \.......................................
243  DATA \.......................................
244  DATA \.......................................
245  DATA \.......................................
246  DATA \.......................................
247  DATA \.......................................
248  DATA \.......................................
249  DATA \.......................................
250  DATA \.......................................
251  DATA \.......................................
252  DATA \.......................................
253  DATA \.......................................
254  DATA \.......................................
255  DATA \.......................................
256  DATA \.......................................
257  DATA \.......................................
258  DATA \.......................................
259  DATA \.......................................
260  DATA \.......................................
261  DATA \.......................................
262  DATA \.......................................
263  DATA \.......................................
264  DATA \.......................................
265  DATA \.......................................
266  DATA \.......................................
267  DATA \.......................................
268  DATA \.......................................
269  DATA \.......................................
270  DATA \.......................................
271  DATA \.......................................
272  DATA \.......................................
273  DATA \.......................................
274  DATA \.......................................
275  DATA \.......................................
276  DATA \.......................................
277  DATA \.......................................
278  DATA \.......................................
279  DATA \.......................................
280  DATA \.......................................
281  DATA \.......................................
282  DATA \.......................................
283  DATA \.......................................
284  DATA \.......................................
285  DATA \.......................................
286  DATA \.......................................
287  DATA \.......................................
288  DATA \.......................................
289  DATA \.......................................
290  DATA \.......................................
291  DATA \.......................................
292  DATA \.......................................
293  DATA \.......................................
294  DATA \.......................................
295  DATA \.......................................
296  DATA \.......................................
297  DATA \.......................................
298  DATA \.......................................
299  DATA \.......................................
300  DATA \.......................................
301  DATA \.......................................
302  DATA \.......................................
303  DATA \.......................................
304  DATA \.......................................
305  DATA \.......................................
306  DATA \.......................................
307  DATA \.......................................
308  DATA \.......................................
309  DATA \.......................................
310  DATA \.......................................
311  DATA \.......................................
312  DATA \.......................................
313  DATA \.......................................
314  DATA \.......................................
315  DATA \.......................................
316  DATA \.......................................
317  DATA \.......................................
318  DATA \.......................................
319  DATA \.......................................
320  DATA \.......................................
321  DATA \.......................................
322  DATA \.......................................
323  DATA \.......................................
324  DATA \.......................................
325  DATA \.......................................
326  DATA \.......................................
327  DATA \.......................................
328  DATA \.......................................
329  DATA \.......................................
330  DATA \.......................................
331  DATA \.......................................
332  DATA \.......................................
333  DATA \.......................................
334  DATA \.......................................
335  DATA \.......................................
336  DATA \.......................................
337  DATA \.......................................
338  DATA \.......................................
339  DATA \.......................................
340  DATA \.......................................
341  DATA \.......................................
342  DATA \.......................................
343  DATA \.......................................
344  DATA \.......................................
345  DATA \.......................................
346  DATA \.......................................
347  DATA \.......................................
348  DATA \.......................................
349  DATA \.......................................
350  DATA \.......................................
400  REM <CTRL-J><CTRL-J>SET PRINTER SLOT<CTRL-J><CTRL-J>
410  LET SL = 1
450  REM <CTRL-J><CTRL-J>DISK SYSTEM??<CTRL-J><CTRL-J>
460  IF  PEEK(994) + PEEK(1001) = 192  THEN DISK = 1
470  IF DISK  THEN  PRINT  CHR$(4)"NOMON C,I,O": HOME
500  REM <CTRL-J><CTRL-J>GET ADDRESS OF FIRST DATA STATEMENT<CTRL-J><CTRL-J>
510  LET START = ( PEEK(103) + PEEK(104) *256 +458)
550  REM <CTRL-J><CTRL-J>SET FAST/SLOW SEARCH<CTRL-K><CTRL-K><CTRL-J><CTRL-J>
560  LET OP = 0
570  GOTO 25000
700  REM <CTRL-J><CTRL-J>ACTIVATE PRINTER<CTRL-J><CTRL-J>
710  PR# SL: RETURN
750  REM <CTRL-J><CTRL-J>DE-ACTIVATE PRINTER<CTRL-J><CTRL-J>
760  PR# 0: RETURN
800  REM <CTRL-J><CTRL-J>END ROUTINE<CTRL-J><CTRL-J>
810  IF MF = 0  THEN 890
820  IF DISK  THEN  PRINT  CHR$(4)"SAVE PHONE LIST": TEXT : HOME : VTAB 22: CALL 976: END
830  HOME : VTAB 11: PRINT "INSERT A NEW TAPE INTO THE RECORDER, SET";: PRINT "ON RECORD, AND PRESS 'RETURN' ";: INPUT "";S$
840  FOR I = 1 TO 1500: NEXT : SAVE : FOR I = 1 TO 2000: NEXT : SAVE
850  HOME : VTAB 12: PRINT "THE PROGRAM AND DATA HAVE BEEN SAVED!!<CTRL-G>": VTAB 22: END
890  TEXT : HOME : VTAB 22: END
1000  REM <CTRL-J><CTRL-J>SEARCH<CTRL-J><CTRL-J>
1005  GOSUB 3000: IF OP = 1  THEN 1010
1006  HOME : VTAB 9: HTAB 5: PRINT "WOULD YOU LIKE TO SEARCH BY": PRINT : HTAB 10: PRINT "1  WORD (FAST)": HTAB 7: PRINT "OR 2  CHARACTER (SLOW)"
1007  VTAB 14: CALL  -868: HTAB 20: INPUT "WHICH: ";SK$:SK =  VAL(SK$): IF SK < >1  AND SK < >2  OR  LEN(SK$) >1  THEN  PRINT "<CTRL-G>": GOTO 1007
1010  HOME : VTAB 11: HTAB 5: PRINT "PLEASE ENTER THE SEARCH KEY:": VTAB 13: HTAB 5: INPUT "";S$: IF S$ = ""  THEN 25000
1012  IF PR  THEN  GOSUB 700: PRINT " ": PRINT " "
1015  HOME : VTAB 1: PRINT " NAME                      PHONE NUMBER": PRINT "----------------------------------------"
1017  IF PR  THEN  GOSUB 750
1018  IF S = 2  THEN 2510
1020  VTAB 12: CALL  -868: HTAB 12: INVERSE : PRINT "<< SEARCHING >>": NORMAL :VT = 2
1025  RESTORE : READ Z
1030  LET FO = 0: FOR I = 1 TO NR
1040  READ NA$: IF  LEFT$(NA$,1) =  CHR$(92)  THEN 1040
1045  IF SK = 0  OR SK = 1  THEN  IF  LEFT$(NA$, LEN(S$)) < >S$  THEN 1075
1050  FOR II = 1 TO  LEN(NA$)
1060  IF  MID$ (NA$,II, LEN(S$)) = S$  THEN FO = FO +1: GOSUB 1100: GOTO 1075
1070  NEXT II
1075  NEXT I: IF FO  THEN 1200
1080  VTAB 12: CALL  -868: HTAB 12: INVERSE : PRINT "<< NOT FOUND >>": NORMAL : IF PR  THEN  GOSUB 700: FOR S = 1 TO 4: PRINT " ": NEXT : GOSUB 750
1090  PRINT  CHR$(7): FOR I = 1 TO 1500: NEXT I: GOTO 25000
1099  STOP
1100  REM <CTRL-J><CTRL-J>GOT ONE!<CTRL-J><CTRL-J>
1102  LET VT = VT +1: IF VT > = 21  AND PR < >1  THEN  GOSUB 1300
1104  IF FO = 1  THEN  VTAB 12: CALL  -868
1105  IF PR  THEN  GOSUB 700
1110  VTAB VT: HTAB 1: PRINT NA$
1120  IF PR  THEN  GOSUB 750
1140  IF I < = NR  THEN  RETURN
1200  IF PR  THEN  GOSUB 700: PRINT " ": PRINT " ": PRINT " ": PRINT " ": GOSUB 750
1210  VTAB 22: CALL  -868: PRINT "THAT'S ALL OF THEM! - PRESS 'RETURN' ";: INPUT "";S$: GOTO 25000
1299  STOP
1300  REM <CTRL-J><CTRL-J>GOT A FULL PAGE<CTRL-J><CTRL-J>
1310  VTAB 22: CALL  -958: PRINT "ENTER 'RTN' TO CONT - 'ESC' FOR MENU ";: GET T$
1320  IF T$ =  CHR$(27)  THEN  POP : GOTO 25000
1330  IF T$ =  CHR$(13)  THEN  VTAB 3: HTAB 1: CALL  -958:VT = 3: RETURN
1340  PRINT  CHR$(7): GOTO 1300
2499  STOP
2500  REM <CTRL-J><CTRL-J>LIST EVERYTHING<CTRL-J><CTRL-J>
2504  GOSUB 3000
2505  GOTO 1012
2510  RESTORE : READ Z
2530  LET VT = 2:FO = 0: FOR I = 1 TO NR
2540  READ NA$: IF  LEFT$(NA$,1) =  CHR$(92)  AND I < = NR  THEN 2540
2542  GOSUB 1100
2545  IF VT > = 22  THEN VT = 2: VTAB 3: CALL  -958
2550  NEXT I
2560  GOTO 1200
3000  REM <CTRL-J><CTRL-J>IS DATA FILE EMPTY?<CTRL-J><CTRL-J>
3010  HOME : RESTORE : IF NR = 0  THEN  VTAB 12: HTAB 9: INVERSE : PRINT "<< NO NAMES ON FILE  >><CTRL-G>": NORMAL : FOR I = 1 TO 2000: NEXT I: POP : GOTO 25000
3020  RETURN
4000  REM <CTRL-J><CTRL-J>ENTER LISTINGS<CTRL-J><CTRL-J>
4010  HOME : IF NR > = 150  THEN  VTAB 12: HTAB 12: PRINT "DATA TABLE FULL!<CTRL-G>": FOR I = 1 TO 2000: NEXT : GOTO 25000
4020  POKE 32,3: VTAB 10: CALL  -958: PRINT "ENTER NEW NAME AND PRESS 'RETURN'.": PRINT "(USE NO COMMAS, COLONS OR QUOTES.": PRINT "TWENTY-FIVE CHARACTERS, MAXIMUM.)"
4030  VTAB 14: INPUT "-> ";A$: GOSUB 6100:NN$ = B$: IF NN$ = ""  AND S = 5  THEN  POKE 32,0: POP : GOTO 25000
4035  IF NN$ = ""  THEN  POKE 32,0: GOTO 25000
4040  IF  LEN(NN$) >25  THEN  PRINT "<CTRL-G>": GOTO 4020
4050  VTAB 10: CALL  -958: PRINT "ENTER NEW NUMBER THEN PRESS 'RETURN'.": PRINT "(USE THE FORMAT: XXX XXX XXXX)"
4060  VTAB 13: INPUT "-> ";A$: GOSUB 6100:NP$ = B$: IF NP$ = ""  AND S = 5  THEN  POKE 32,0: POP : GOTO 25000
4065  IF NP$ = ""  THEN  POKE 32,0: GOTO 25000
4070  IF  LEN(NP$) < >12  THEN  PRINT "<CTRL-G>": GOTO 4050
4100  REM <CTRL-J><CTRL-J>IS ENTRY CORRECT?<CTRL-J><CTRL-J>
4110  TEXT : HOME : VTAB 8: PRINT "HERE IS THE ";: INVERSE : PRINT "NAME";: NORMAL : PRINT " ENTRY:": VTAB 10: HTAB 14: PRINT NN$
4120  VTAB 12: PRINT "AND THE ";: INVERSE : PRINT "PHONE NUMBER";: NORMAL : PRINT ":": VTAB 14: HTAB 14: PRINT NP$
4140  VTAB 18: HTAB 8: CALL  -868: INPUT "ARE THEY CORRECT (Y/N) ";S$: IF  LEFT$(S$,1) = "Y"  THEN 4180
4150  IF  LEFT$(S$,1) < >"Y"  AND S = 5  THEN  POP : GOTO 6000
4160  IF  LEFT$(S$,1) < >"N"  THEN  PRINT "<CTRL-G>": GOTO 4100
4170  GOTO 4000
4175  IF S = 5  THEN 4200
4180  IF S = 5  THEN 4200
4190  LET UD = 1
4200  REM <CTRL-J><CTRL-J>PAD TO 40 CHARACTERS<CTRL-J><CTRL-J>
4210  FOR I =  LEN(NN$) TO (39 - LEN(NP$)):NN$ = NN$ +".": NEXT
4220  LET NN$ = NN$ +NP$: IF S = 5  THEN  RETURN
4250  REM <CTRL-J><CTRL-J>UPDATE DATA NUMBER<CTRL-J><CTRL-J>
4260  RESTORE : READ T:T = T +UD:CU = (START -11)
4270  LET T$ =  STR$(T): FOR I = 1 TO  LEN(T$)
4280  POKE (CU +I), ASC( MID$ (T$,I,1)): NEXT
4290  IF S = 4  THEN  RETURN
4300  REM <CTRL-J><CTRL-J>FIND EMPTY DATA LINE<CTRL-J><CTRL-J>
4310  READ T$: IF  LEFT$(T$,1) < > CHR$(92)  THEN 4310
4320  LET LN =  PEEK(123) + PEEK(124) *256
4350  REM <CTRL-J><CTRL-J>CALCULATE OFFSET<CTRL-J><CTRL-J>
4360  LET CU = (START +((LN -201) *46))
4400  REM <CTRL-J><CTRL-J>POKE DATA LINE<CTRL-J><CTRL-J>
4410  FOR I = CU TO (CU +39)
4420  POKE I, ASC( MID$ (NN$,I +1 -CU,1)): NEXT
4450  REM <CTRL-J><CTRL-J>SET UPDATE FLAG<CTRL-J><CTRL-J>
4460  LET MF = MF +1: IF S = 4  OR S = 5  THEN  RETURN
4470  GOTO 25000
4499  STOP
5000  REM <CTRL-J><CTRL-J>DELETE DATA CONTENTS<CTRL-J><CTRL-J>
5005  HOME : GOSUB 3000
5010  HOME : VTAB 10: PRINT "PLEASE ENTER THE NAME OF THE PARTY YOU": PRINT "WISH DELETED FROM THE DIRECTORY AND": PRINT "PRESS 'RETURN'."
5020  VTAB 14: INPUT "-> ";K$: IF K$ = ""  AND S = 5  THEN  POP : GOTO 25000
5030  IF K$ = ""  THEN 25000
5050  REM <CTRL-J><CTRL-J>FIND AN EXACT MATCH<CTRL-J><CTRL-J>
5060  RESTORE : READ Z:UU = 1
5070  READ NA$: IF  LEFT$(NA$, LEN(K$)) = K$  THEN 5100
5075  IF  LEFT$(NA$,1) =  CHR$(92)  AND UU < = NR  THEN 5070
5080 UU = UU +1
5081  IF UU < = NR  THEN 5070
5082  HOME : GOTO 25000
5100  REM <CTRL-J><CTRL-J>FOUND A MATCH<CTRL-J><CTRL-J>
5110  LET LN =  PEEK(123) + PEEK(124) *256:UU = UU +1
5120  HOME : VTAB 11: PRINT NA$: IF S = 5  THEN  RETURN
5130  VTAB 13: CALL  -868: INPUT "DO YOU WISH TO DELETE THIS DATA (Y/N) ";S$: IF  LEFT$(S$,1) = "Y"  THEN 5200
5140  IF  LEFT$(S$,1) < >"N"  THEN  PRINT "<CTRL-G>": GOTO 5130
5150  GOTO 5081
5200  REM <CTRL-J><CTRL-J>OK THEN, KILL IT!<CTRL-A><CTRL-J><CTRL-J>
5210  LET UD =  -1: GOSUB 4250
5220  LET CU = (START +((LN -201) *46))
5230  POKE CU, ASC( CHR$(92))
5240  GOSUB 4450: GOTO 25000
6000  REM <CTRL-J><CTRL-J>EDIT A DATA LINE<CTRL-J><CTRL-J>
6010  HOME : GOSUB 3000
6012  HOME : VTAB 10: PRINT "PLEASE ENTER THE NAME OF THE PARTY WHOSE";: PRINT "LISTING YOU WISH TO EDIT AND PRESS": PRINT "'RETURN'.": GOSUB 5020
6020  VTAB 13: CALL  -868: INPUT "DO YOU WISH TO EDIT THIS DATA (Y/N) ";S$: IF S$ = ""  THEN 25000
6030  IF  LEFT$(S$,1) = "Y"  THEN NN$ = NA$: GOTO 6050
6035  IF  LEFT$(S$,1) = "N"  THEN  GOSUB 5070
6040  PRINT "<CTRL-G>": GOTO 6020
6050  REM <CTRL-J><CTRL-J>GO EDIT THE LINE<CTRL-J><CTRL-J>
6060  HOME : VTAB 8: PRINT NN$: GOSUB 4020: GOSUB 4360
6070  GOTO 25000
6100  REM  <CTRL-J><CTRL-J>REMOVE CONTROL CHARS.<CTRL-J><CTRL-J>
6105 B$ = ""
6107  IF   NOT  LEN(A$)  THEN  RETURN
6110  FOR I = 1 TO  LEN(A$)
6120  IF  ASC( MID$ (A$,I,1)) >26  THEN B$ = B$ + MID$ (A$,I,1)
6130  NEXT I
6140  RETURN
24000  REM <CTRL-J><CTRL-J>PRINTER ON/OFF<CTRL-J><CTRL-J>
24010  LET PR =   NOT PR: GOTO 25050
24020  STOP
25000  REM <CTRL-J><CTRL-J>MAIN MENU<CTRL-J><CTRL-J>
25005  RESTORE : READ NR:NR = NR -1000
25010  TEXT : HOME : VTAB 1: PRINT "----------------------------------------";: INVERSE
25020  PRINT " APPLE COMPUTER, INC.        PHONE LIST ";: NORMAL : PRINT "----------------------------------------"
25030  PRINT "PROGRAM CURRENTLY CONTAINS "NR" LISTING";: IF NR < >1  THEN  PRINT "S";
25040  PRINT : PRINT "ROOM FOR "(150 -NR)" ADDITIONAL LISTINGS"
25050  VTAB 8: PRINT "THE PRINTER IS";: IF   NOT PR  THEN  PRINT "  OFF";
25055  IF   NOT PR  THEN  VTAB 9: PRINT "                                   ": GOTO 25070
25060  PRINT " ";: FLASH : PRINT " ON ": NORMAL
25070  VTAB 10: PRINT "YOU MAY CHOOSE FROM THE FOLLOWING:": POKE 32,5: PRINT : PRINT
25080  PRINT "1  SEARCH FOR A LISTING": PRINT "2  LIST THE ENTIRE FILE"
25090  PRINT "3  ENTER NEW LISTINGS": PRINT "4  DELETE A LISTING"
25100  PRINT "5  EDIT A LISTING": PRINT "6  PRINTER ON/OFF"
25110  PRINT "7  EXIT THIS PROGRAM": POKE 32,0: PRINT
25120  POKE 32,0: PRINT
25130  VTAB 22: HTAB 20: CALL  -868: INPUT "WHICH: ";S$:S =  VAL(S$)
25140  IF S <1  OR S >7  THEN  PRINT  CHR$(7): GOTO 25130
25150  ON S GOTO 1000,2500,4000,5000,6000,24000,800
25160  STOP
65533  REM <CTRL-J><CTRL-J><CTRL-J>
65534  REM APPLE COMPUTER, INC.
65535  REM  COPYRIGHT 4/1/1979